0x126A90C

// Visit http://forum.gamedeception.net/
#include <ida.idc>
 
static main()
{
	auto disasm, sPath, hFile, dwStartFunc, dwEndFunc, s_descriptor, disasmAddr, addr, dwStringPtr, string;
 
	// Function name: MirrorInitialize
	dwStartFunc = FindBinary( INF_BASEADDR, SEARCH_DOWN, "55 89 E5 57 56 53 81 EC 8C 00 00 00 C7 45 E4" );
 
	if ( dwStartFunc == BADADDR ){
		Message("Unable to find address for MirrorInitialize, aborting...\n");
		return;
	}
 
	// store it where our database file is!
	sPath = ExtractPath( GetIdbPath() ) + "Objects_Enum.h";
 
	hFile = fopen( sPath, "w" );
	if( hFile != -1 )
	{
		fprintf( hFile, "// %s\n", GetWoWVersionString() );
		fprintf( hFile, "/*----------------------------------\n" );
		fprintf( hFile, "WoW Offset Dumper 14545 - IDC Script\n" );
		fprintf( hFile, "by Tanaris4\n\n" );
		fprintf( hFile, "Credits:\n" );
		fprintf( hFile, "kynox, bobbysing, Patrick, Dominik, Azorbix\n" );
		fprintf( hFile, "-----------------------------------*/\n\n" );
 
		// find the end of the function (search for "retn")
		dwEndFunc = dwStartFunc;
		do{
			disasm = GetDisasm( dwEndFunc );
 
			if ( strstr( disasm, "retn" ) > -1 )
				break;
 
			dwEndFunc++;
		} while ( 1 );
 
		disasmAddr = dwStartFunc;
 
		do{
			auto i, dwEnumId, szPrefix, dwFieldAddr, lastIndex;
 
			disasm = GetDisasm( disasmAddr );
 
			if ( disasmAddr == BADADDR || disasmAddr > dwEndFunc ){
        		break;
        	}
 
			// searching for: mov     [ebp+var_1C], offset dword_10BAE88
			if ( strstr( disasm, "mov" ) > -1 && strstr( disasm, "off" ) > -1 ){
 
				addr = GetOperandValue(disasmAddr, 1);
 
				dwStringPtr = Dword(addr-0x8);
				string = GetString( dwStringPtr, -1, ASCSTR_C );
 
				// is this a match?
				if ( strlen(string) > 0 ){
 
					szPrefix = getPrefix( string );
					if ( strlen(szPrefix) == 0 ){
						continue;
					}
 
					s_descriptor = getStructNameForString(string);
 
					// invalid descriptor?
					if ( strlen(s_descriptor) == 0 ){
						continue;
					}
 
					fprintf( hFile, "// Descriptors: 0x%08X\nenum %s\n{\n", addr-0x8, s_descriptor );
					i = 0;
 
					// create our enum
					dwEnumId = AddEnum( -1, s_descriptor, 0x1100000 );
 
					// update the name in IDA
					MakeName( addr, s_descriptor );
 
					// re-initialize some stuff
					addr = addr - 0x8;
					lastIndex = -1;
 
					// loop through all descriptors
					while ( getPrefix( string ) != "" ){
 
						auto dwIndex;
 
						dwStringPtr = Dword(addr);
						string = GetString( dwStringPtr, -1, ASCSTR_C );
 
						if ( strlen(string) == 0 ){
							break;
						}
 
						dwIndex = Dword( addr + 4 );
 
						// this makes 0 sense, we're done!
						if ( dwIndex < lastIndex ){
							break;
						}
 
						// since IDA didn't do this for us!
						MakeDword(addr);
						MakeDword(addr-0x14);
 
						AddConstEx( dwEnumId, string, dwIndex * 4, -1 );
						fprintf( hFile, "\t%s = 0x%X,\n", string, dwIndex * 4 );
 
						addr = addr + 0x14;
						i++;
						lastIndex = dwIndex;
					}
 
					fprintf( hFile, "\tTOTAL_%s_FIELDS = 0x%X\n", szPrefix, i );
					fprintf( hFile, "};\n" );
 
				}
 
 
			}
 
			disasmAddr = NextHead( disasmAddr, dwEndFunc );
		} while( 1 );
	}
 
	fclose( hFile );
 
	Message( "Successfully dumped to %s\n", sPath );
}
 
static getPrefix( string ){
 
		// unique case
	if ( strstr( string, "OBJECT_FIELD_CREATED_BY" ) == 0 ){
		return "GAMEOBJECT";
	}
	else if ( strstr( string, "ITEM_" ) > -1 ){
		return "ITEM";
	}
	else if ( strstr( string, "CONTAINER_" ) > -1 ){
		return "CONTAINER";
	}
	else if ( strstr( string, "UNIT_" ) > -1 ){
		return "UNIT";
	}
	else if ( strstr( string, "PLAYER_" ) > -1 ){
		return "PLAYER";
	}
	else if ( strstr( string, "GAMEOBJECT_" ) > -1 ){
		return "GAMEOBJECT";
	}
	else if ( strstr( string, "DYNAMICOBJECT_" ) > -1 ){
		return "DYNAMICOBJECT";
	}
	else if ( strstr( string, "CORPSE_" ) > -1 ){
		return "CORPSE";
	}
	else if ( strstr( string, "OBJECT_" ) > -1 ){
		return "OBJECT";
	}
 
	return "";
}
 
static getStructNameForString( string ){
 
	// unique case
	if ( strstr( string, "OBJECT_FIELD_CREATED_BY" ) == 0 ){
		return "eGameObjectFields";
	}
	else if ( strstr( string, "ITEM_" ) > -1 ){
		return "eItemFields";
	}
	else if ( strstr( string, "CONTAINER_" ) > -1 ){
		return "eContainerFields";
	}
	else if ( strstr( string, "UNIT_" ) > -1 ){
		return "eUnitFields";
	}
	else if ( strstr( string, "PLAYER_" ) > -1 ){
		return "ePlayerFields";
	}
	else if ( strstr( string, "GAMEOBJECT_" ) > -1 ){
		return "eGameObjectFields";
	}
	else if ( strstr( string, "DYNAMICOBJECT_" ) > -1 ){
		return "eDynamicObjectFields";
	}
	else if ( strstr( string, "CORPSE_" ) > -1 ){
		return "eCorpseFields";
	}
	else if ( strstr( string, "OBJECT_" ) > -1 ){
		return "eObjectFields";
	}
 
	return "";
}
 
static ExtractPath( sPath ){
	auto dwIndex;
	for ( dwIndex = strlen( sPath ); strstr( substr( sPath, dwIndex, -1 ), "/" ) && dwIndex > 0; dwIndex-- );
	return substr( sPath, 0, dwIndex + 1 );
}
 
static GetWoWVersionString(){
	auto sVersion, sBuild, sDate;
 
	sVersion = FindBinary( INF_BASEADDR, SEARCH_DOWN, "\"=> WoW Version %s (%s) %s\"" );
 
	if( sVersion == BADADDR )
	{
		Message( "Version format string not found" );
		return 0;
	}
 
	sVersion = DfirstB( sVersion );
 
	if( sVersion == BADADDR )
	{
		Message( "Version string unreferences" );
		return 0;
	}
 
	sVersion = PrevHead( sVersion, 0 );
	sBuild = PrevHead( sVersion, 0 );
	sDate = PrevHead( sBuild, 0 );
 
	sVersion = GetOperandValue( sVersion, 1 );
	sBuild = GetOperandValue( sBuild, 1 );
	sDate = GetOperandValue( sDate, 1 );
 
	sVersion = GetString( sVersion, -1, ASCSTR_C );
	sBuild = GetString( sBuild, -1, ASCSTR_C );
	sDate = GetString( sDate, -1, ASCSTR_C );
 
	return form( "Version: %s  Build number: %s  Build date: %s\n", sVersion, sBuild, sDate );
}{